home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / systems / mac / oztex / mf.hqx / Metafont / mfinputs / metafon.mf < prev    next >
Text File  |  1994-08-19  |  1KB  |  51 lines
  1. beginlogochar("M",18);
  2. x1=x2=leftstemloc; x4=x5=w-x1; x3=w-x3;
  3. y1=y5; y2=y4; bot y1=-o;
  4. top y2=h+o; y3=y1+ygap;
  5. draw z1--z2--z3--z4--z5;
  6. labels(1,2,3,4,5); endchar;
  7.  
  8. beginlogochar("E",14);
  9. x1=x2=x3=leftstemloc;
  10. x4=x6=w-x1+ho; x5=x4-xgap;
  11. y1=y6; y2=y5; y3=y4;
  12. bot y1=0; top y3=h; y2=barheight;
  13. draw z6--z1--z3--z4; draw z2--z5;
  14. labels(1,2,3,4,5,6); endchar;
  15.  
  16. beginlogochar("T",13);
  17. italcorr ht#*slant + .5u#;
  18. if .5w<>good.x .5w: change_width; fi
  19. lft x1=-eps; x2=w-x1; x3=x4=.5w;
  20. y1=y2=y3; top y1=h; bot y4=-o;
  21. draw z1--z2; draw z3--z4;
  22. labels(1,2,3,4); endchar;
  23.  
  24. beginlogochar("A",15);
  25. x1=.5w; x2=x4=leftstemloc; x3=x5=w-x2;
  26. top y1=h+o; y2=y3=barheight;
  27. bot y4=bot y5=-o;
  28. draw z4--z2--z3--z5; super_half(2,1,3);
  29. labels(1,2,3,4,5); endchar;
  30.  
  31. beginlogochar("F",14);
  32. x1=x2=x3=leftstemloc;
  33. x4=w-x1+ho; x5=x4-xgap;
  34. y2=y5; y3=y4; bot y1=-o;
  35. top y3=h; y2=barheight;
  36. draw z1--z3--z4; draw z2--z5;
  37. labels(1,2,3,4,5); endchar;
  38.  
  39. beginlogochar("O",15);
  40. x1=x4=.5w; top y1=h+o; bot y4=-o;
  41. x2=w-x3=good.x(1.5u+s); y2=y3=barheight;
  42. super_half(2,1,3); super_half(2,4,3);
  43. labels(1,2,3,4); endchar;
  44.  
  45. beginlogochar("N",15);
  46. x1=x2=leftstemloc; x3=x4=x5=w-x1;
  47. bot y1=bot y4=-o;
  48. top y2=top y5=h+o; y3=y4+ygap;
  49. draw z1--z2--z3; draw z4--z5;
  50. labels(1,2,3,4,5); endchar;
  51.